//各種クラスのインポート
import flash.display.Loader;
import flash.net.URLLoader;
import flash.net.URLLoaderDataFormat;
import flash.net.URLRequest;
import fl.text.TLFTextField;
import flashx.textLayout.elements.TextFlow;
import flashx.textLayout.formats.TextLayoutFormat;
import flashx.textLayout.formats.BlockProgression;
import flash.filters.DropShadowFilter;
import flash.display.Shape;
import fl.transitions.Tween;
import fl.transitions.easing.*;
import fl.transitions.TweenEvent;

//変数型定義
var coverRec:Shape;
var tw:Tween;
var tfx:Number;
var tfy:Number;

//変数初期値の設定
var txtSize:Number=30;//文字の最大サイズ
var lineHeight:Number=1.2;//ラインハイト120%
var lineNum:int=11;//トゥイーン対象テキストの列数（空白列を含む）
var tf_w:Number=txtSize*lineHeight;//テキスト１列分の幅
var tf_h:Number=350;//テキストフィールドの高さ

//TLFテキストフィールドの作成、属性定義
var tlfTxtF:TLFTextField = new TLFTextField();
var dropShadow:DropShadowFilter =  new DropShadowFilter();
with (tlfTxtF) {
  border=true;
  background=true;
  width=(lineNum+3)*tf_w+tf_w/2;
  height=tf_h;
  x=tfx=20;
  y=tfy=20;
  borderColor=0x999999;
  backgroundColor=0xffffff;
  filters=new Array(dropShadow);
}
addChild(tlfTxtF);

//文字の基本フォーマット（日本語形式縦書）
var baseFmt:TextLayoutFormat = new TextLayoutFormat();
baseFmt.blockProgression=BlockProgression.RL;
baseFmt.locale="ja";
baseFmt.fontFamily="HGS明朝E,HGSMinchoE,ＭＳ Ｐ明朝,MSPMincho,
ヒラギノ明朝 Pro W6,Hiragino Mincho Pro,serif";

//TLFマークアップ形式xmlからのデータ読み込み
var xmlLoader:URLLoader = new URLLoader();
xmlLoader.dataFormat=URLLoaderDataFormat.TEXT;
xmlLoader.addEventListener(Event.COMPLETE, xmlLoad_complete);
xmlLoader.load(new URLRequest("tanka.xml"));

//読み込んだデータにbaseFormatを適用・表示し、トゥイーンを開始
function xmlLoad_complete(evt:Event):void {
  tlfTxtF.tlfMarkup=xmlLoader.data;
  var myTextFlow:TextFlow=tlfTxtF.textFlow;
  myTextFlow.hostFormat=baseFmt;
  myTextFlow.flowComposer.updateAllControllers();
  lineTween(1);
}

//各列のテキストを覆う短冊型矩形をトゥイーン対象列(含空白列)分並べる
for (var i:uint=1; i<=lineNum; i++) {
  var rec_mc:MovieClip = new MovieClip();
  addChild(rec_mc);
  rec_mc.name="rec_mc"+i;
  rec_mc.x=tfx+(lineNum+1-i)*tf_w;
  rec_mc.y=tfy;
  recDraw(rec_mc);
}

//矩形描画関数
function recDraw(mc):void {
  coverRec = new Shape();
  var gr=coverRec.graphics;
  gr.beginFill(0xffffff,1.0);
  gr.drawRect(0,0,tf_w,tf_h);
  gr.endFill();
  mc.addChild(coverRec);
}

//矩形を順次縦方向に縮小して、テキストをだんだん表示する関数
function lineTween(n):void {
  if (n<lineNum+1) {
    var mc=MovieClip(getChildByName("rec_mc"+n));
    mc.y=20+tf_h;
    tw=new Tween(mc,"scaleY",None.easeOut,-1,0,2.5,true);
    tw.addEventListener(TweenEvent.MOTION_FINISH,nextLine);
    function nextLine():void {
      n++;
      lineTween(n);
    }
  }
}