//ビーズのサイズ
var dotSize = 4;
//文字毎のビーズの数
var dotNum = 200;
//文字数
var chNum = 4;
//各文字ムービークリップのsize
var charWidth = 80;
var charHeight = 90;
//表示間隔(ミリ秒)
var interval = 600;
//文字列表示位置（1字目左上）
var x0 = 250;
var y0 = 100;
//ビーズが飛び始める点
var startx = 50;
var starty = 400;

//文字インスタンス
for (i=1; i<=chNum; i++) {
  var char = this.attachMovie("c"+i, "ch"+i, i);
  char._x = x0+charWidth*(i-1);
  char._y = y0;
  char._alpha = 0;
}

//START ボタンリリースで
s_btn.onRelease = function():Void  {
  s_btn.enabled = false;
  s_btnclick = true;
  r_btnclick = false;
  k = 1;
  id = setInterval(initialset, interval);
};
//RESET ボタンリリースで
r_btn.onRelease = function():Void  {
  s_btn.enabled = true;
  r_btn.enabled = false;
  r_btnclick = true;
  s_btnclick = false;
  init();
};

//初期配置
init();
function init():Void {
  k = 1;
  for (j=1; j<=chNum; j++) {
    initialset();
  }
}

//ビーズの初期配置関数
function initialset():Void {
  j = k++;
  for (i=1; i<dotNum; i++) {
    var d = j*dotNum+i;
    mc = attachMovie("dot_mc", "dot"+d, d);
    mc._width = mc._height = dotSize;
    mc.target_mc = _root["ch"+j];
    mc._x = mc.x0 = startx;
    mc._y = mc.y0 = starty;
    var color = new Color(mc);
    color.setRGB(Math.floor(Math.random()*256*256*256));
    mc.finished = false;
    mc.num = j;
    target(mc);
  }
}

//移動先の文字を含む矩形領域を設定する関数
function target(mc):Void {
  mc.targetx = mc.target_mc._x+charWidth*Math.random();
  mc.targety = mc.target_mc._y+charHeight*Math.random();
  arrangeMc(mc);
}

//移動先の文字領域を設定する関数
function arrangeMc(mc):Void {
  if (mc.finished == false) {
    mc.onEnterFrame = function() {
      if (s_btnclick) {
        this._visible = false;
        this._x = this.targetx;
        this._y = this.targety;
        if (!this.target_mc.hitTest(this._x, this._y, true)) {
          target(this);
        } else {
          this._visible = true;
          this._x = this.x0;
          this._y = this.y0;
          this.atnow = getTimer();
          this.finished = true;
          delete this.onEnterFrame;
          this.onEnterFrame = toTarget;
        }
      } else {
        this.onEnterFrame = toTarget;
      }
    };
  }
}

//文字領域に移動する関数
function toTarget():Void {
  if ((getTimer() - this.atnow) > 2 * this.num) {
    this._x += (this.targetx - this._x) / 7;
    a = this.targetx - (this.targety - starty) / this.targetx / 0.012*(0.5+this.num);
    this._y = 0.012/(0.5+this.num)* this._x * (this._x - a) + starty;
  }
  btn.enabled = true;
  if (Math.abs(this._x-this.targetx)<3) {
    this._x = this.targetx;
    this._y = this.targety;
    delete this.onEnterFrame;
    if (this.num == chNum) {
      clearInterval(id);
    }
  }
  r_btn.enabled = true;
}