//DateChooser インスタンスの作成
this.createClassObject(mx.controls.DateChooser, "my_dc", 1);
//配置座標
my_dc._x = 10;
my_dc._y = 10;
//サイズ
my_dc.setSize(160, 170);
//月表示
my_dc.monthNames = ["1月", "2月", "3月", "4月", "5月", "6月", "7月", "8月",
 "9月", "10月", "11月", "12月"];
_global.styles.HeaderDateText.setStyle("color", 0xFFFFFF);
//最初の列に表示する曜日(日-土：0-6)
my_dc.firstDayOfWeek = 1;
//曜日表示
my_dc.dayNames = ["日", "月", "火", "水", "木", "金", "土"];
_global.styles.WeekDayStyle.setStyle("color", 0x0033FF);
//背景色
my_dc.setStyle("headerColor", 0x0066FF);
my_dc.setStyle("backgroundColor", 0x66CCFF);
//今日の日付
_global.styles.TodayStyle.setStyle("color", 0xFFFFFF);
//フォントサイズ
my_dc.setStyle("fontSize", 11);
//フォント
my_dc.setStyle("fontFamily ", "Georgia");
//ロールオーバーと選択日の色
my_dc.setStyle("themeColor", "haloBlue");
//全体にドロップシャドウ
import flash.filters.DropShadowFilter;
var filter:DropShadowFilter = new DropShadowFilter();
var filterArray:Array = new Array();
filterArray.push(filter);
my_dc.filters = filterArray;

//表示用テキストフィールド、ムービークリップ
this.createTextField("date_txt", 2, 190, 15, 110, 20);
this.createTextField("moonage_txt", 3, 190, 35, 110, 20);
this.createEmptyMovieClip("moonDisplay", 4);
moonDisplay._x = 180;
moonDisplay._y = 60;

//当日の月齢表示
//Date オブジェクトを作成
now_date = new Date(); 
//日時を取得
var nowYear = now_date.getFullYear();
var nowMonth = now_date.getMonth()+1;
var nowDate = now_date.getDate();

//表示する形式を設定
todayDate = nowYear + " 年 " + nowMonth + " 月 " + nowDate + " 日";

//テキストフィールドに本日の日付を表示
date_txt.text = todayDate;

//本日の月齢写真表示
moonageDisplay(nowYear,nowMonth,nowDate);

//選択日の月齢イメージの表示
//DataChooser 用のイベントリスナーを作成
myDateListener = new Object();

// チェンジイベントハンドラ
myDateListener.change = function(eventObj) {
        var eventSource = eventObj.target;
        var theSelectedDate = eventSource.selectedDate;
        // format the date
        var theDate = theSelectedDate.getDate();
        var theMonth = theSelectedDate.getMonth()+1;
        var theYear = theSelectedDate.getFullYear();
        var formattedDate = theYear+" 年 "+theMonth+" 月 "+theDate+" 日";
        // 選択された日付を表示
        date_txt.text = formattedDate;
        //選択した日の月齢写真表示
        moonageDisplay(theYear,theMonth,theDate);
        
};
// イベントリスナーの登録
my_dc.addEventListener("change", myDateListener);

function moonageDisplay(theYear,theMonth,theDate) {
        //月齢計算
        if (theMonth == 1 || theMonth == 2) {
                var moonAge = (((theYear-2009)%19)*11+theMonth+theDate)%30+2;
        } else {
                moonAge = (((theYear-2009)%19)*11+theMonth+theDate)%30;
        }
        if (moonAge<=0) {
                moonAge += 30;
        }
        //月齢・画像表示
        moonage_txt.text = "月齢：" + moonAge;
        var jpg = "img/" + moonAge + ".jpg";
        moonDisplay.loadMovie(jpg);
}